[phpBB Debug] PHP Warning: in file /includes/functions.php on line 4559: Invalid argument supplied for foreach()
Dampfradioforum • Thema anzeigen - PSpice Model ECF82

Dampfradioforum

Röhrenradioforum: Das Forum für alle Freunde alter Röhrenradios, Kofferradios und Röhrentechnik!
Aktuelle Zeit: Do Mär 28, 2024 17:41

Alle Zeiten sind UTC + 1 Stunde




Ein neues Thema erstellen Auf das Thema antworten  [ 19 Beiträge ]  Gehe zu Seite 1, 2  Nächste
Autor Nachricht
 Betreff des Beitrags: PSpice Model ECF82
BeitragVerfasst: Sa Nov 18, 2017 11:34 
Offline

Registriert: So Sep 24, 2017 21:56
Beiträge: 82
Kenntnisstand: Elektrotechnischer Beruf/ Studium
Hallo Leute,

ich will eine Schaltung mit ECF82 simulieren. Im Internet hab ich folgende Pspice Modelle gefunden, die leider nicht funktionieren.


.SUBCKT ECF82P 1 2 3 4 ; A G2 G1 C (Pentode)
* Universal Vademecum (1960) AKA 6U8
* library format: LTSpice 31-May-2008
X1 1 2 3 4 PENTODE1 MU=37.97 EX=1.350 KG1=849.8 KG2=4500 KP=90.97 KVB=20.1 VCT=0.00 RGI=2000 CCG=5.7p CPG1=0.6p CCP=4.1p ;
.ENDS ECF82P


.SUBCKT ECF82T 1 2 3 ; P G C (Triode)
* WF data sheet AKA 6U8
* library format: LTSpice 31-May-2008
X1 1 2 3 TRIODE MU=49.87 EX=1.255 KG1=323.2 KP=106.38 KVB=300.0 VCT=0.00 RGI=2000 CCG=3.0p CGP=2.2p CCP=2.3p ;
.ENDS ECF82T

Diese Modelbeschreibungen unterscheiden sich von den Modellen, die bei mir funktionieren.
Zum Beispiel ECC83(12AX7) Model macht keine Probleme.

.SUBCKT 12AX7A P G K
E1 2 0 VALUE={45+V(P,K)+95.43*V(G,K)}
R1 2 0 1.0K
Gp P K VALUE={1.147E-6*(PWR(V(2),1.5)+PWRS(V(2),1.5))/2}
Cgk G K 1.6P
Cgp G P 1.7P
Cpk P K 0.46P
.ENDS 12AX7A

Sind diese Modelbeschreibungen fehlerhaft? Oder sind die nur für LTspice?
Für Simulationen benutze ich Altium Designer und Pspice Modele werden erkannt und akzeptiert.
Oder hat jemand ein anderes Model für ECF82?

Viele Grüße,
Eugen


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: PSpice Model ECF82
BeitragVerfasst: Sa Nov 18, 2017 13:51 
Offline

Registriert: Do Sep 29, 2016 2:10
Beiträge: 93
Kenntnisstand: Weitergehende Kenntnisse (Hobby)
Hallo Eugen,

Deine erst genannten Modell-Codes beinhalten auch nur die Parameterzuweisungen. Die eigentlichen Berechnungsvorschriften fehlen.

Eigentlich müsste sich den Parameterzuweisungen Folgendes (sprich die eigentlichen Modellgleichungen) anschließen:
Triode:
Code:
E1  7 0 VALUE={V(1,3)/KP*LOG(1+EXP(KP*(1/MU+(V(2,3)+VCT)/SQRT(KVB+V(1,3)*V(1,3)))))}
RE1 7 0 1G
G1  1 3 VALUE={(PWR(V(7,0),EX)+PWRS(V(7,0),EX))/KG1}
RCP 1 3 1G    ; TO AVOID FLOATING NODES IN MU-FOLLOWER
C1  2 3 {CCG}  ; CATHODE-GRID
C2  2 1 {CGP}  ; GRID=PLATE
C3  1 3 {CCP}  ; CATHODE-PLATE
D3  5 3 DX     ; FOR GRID CURRENT
R1  2 5 {RGI}  ; FOR GRID CURRENT

.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N) ; diode used by the Triode, Pentode Beam Tetrode models
.ENDS


Pentode:
Code:
RE1  7 0  1MEG    ; DUMMY SO NODE 7 HAS 2 CONNECTIONS
E1   7 0  VALUE={V(2,4)/KP*LOG(1+EXP((1/MU+V(3,4)/V(2,4))*KP))}   ; E1 BREAKS UP LONG EQUATION FOR G1.
G1   1 4  VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1*ATAN(V(1,4)/KVB)}
G2   2 4  VALUE={(EXP(EX*(LOG((V(2,4)/MU)+V(3,4)))))/KG2}
* G2   2 4  VALUE={PWR(V(2,4)/MU+V(3,4),EX)/KG2}
RCP  1 4  1G      ; FOR CONVERGENCE   A  - C
C1   3 4  {CCG}   ; CATHODE-GRID 1   C  - G1
C2   1 3  {CPG1}  ; GRID 1-PLATE   G1 - A
C3   1 4  {CCP}   ; CATHODE-PLATE   A  - C
R1   3 5  {RGI}   ; FOR GRID CURRENT   G1 - 5
D3   5 4  DX      ; FOR GRID CURRENT   5  - C

.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N) ; diode used by the Triode, Pentode Beam Tetrode models
.ENDS


Die Aufrufe TRIODE und PENTODE1 deiner Codeschnipsel referenzieren auf die von mir genannten Modellgleichungen und finden sich i.d.R. am Ende des Codes von Tube-Librarys und werden für alle Röhren in der selben Art genutzt, nur mit unterschiedlichen Parametern.

Viele Grüße
Steffen


Zuletzt geändert von Schiller72 am Sa Nov 18, 2017 16:41, insgesamt 1-mal geändert.

Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: PSpice Model ECF82
BeitragVerfasst: Sa Nov 18, 2017 16:14 
Offline
Benutzeravatar

Registriert: Sa Jan 09, 2010 15:49
Beiträge: 2705
Wohnort: Sauerland
Kenntnisstand: Elektrotechnischer Beruf/ Studium
Hallo,

bei Pocnet wird erwähnt, daß die ECF82 baugleich mit der 6U8 ist, und von der gibt es ein Modell:
http://www.mif.pg.gda.pl/homepages/fran ... _Tubes.cir

Edit: Hups, ich sehe gerade, das war nix Neues für Dich. Deine Daten sind auch aus diesem Dokument. Die zugehörigen Röhrengleichungen scheint es auch zu enthalten. Ich probiere das Modell mal aus.

Edit: Es funktioniert.

Dateianhang:
ECF82 Ausgangskennlinie.png
ECF82 Ausgangskennlinie.png [ 26.48 KiB | 11948-mal betrachtet ]


Hier ist das asc-File. Diese Simulation gibt die Ausgangskennlinien aus; Du kannst sie ja mal mit denen aus dem Datenblatt vergleichen.
Code:
Version 4
SHEET 1 952 680
WIRE -240 80 -528 80
WIRE -224 80 -240 80
WIRE -224 112 -224 80
WIRE -144 176 -176 176
WIRE -80 176 -144 176
WIRE -336 192 -352 192
WIRE -272 192 -336 192
WIRE -528 240 -528 80
WIRE -352 240 -352 192
WIRE -80 240 -80 176
WIRE -528 352 -528 320
WIRE -352 352 -352 320
WIRE -352 352 -528 352
WIRE -256 352 -256 240
WIRE -256 352 -352 352
WIRE -80 352 -80 320
WIRE -80 352 -256 352
WIRE -256 368 -256 352
FLAG -256 368 0
FLAG -240 80 a
FLAG -336 192 g1
FLAG -144 176 g2
SYMBOL pentode -224 176 R0
WINDOW 0 -83 -72 Left 2
WINDOW 3 -100 -46 Left 2
WINDOW 38 -100 -43 Left 2
SYMATTR InstName U1
SYMATTR Value ""
SYMATTR SpiceModel ECF82P
SYMBOL voltage -528 224 R0
WINDOW 123 0 0 Left 2
WINDOW 39 24 132 Left 2
SYMATTR InstName Va
SYMATTR Value 250
SYMBOL voltage -352 224 R0
WINDOW 123 24 132 Left 2
WINDOW 39 0 0 Left 2
WINDOW 3 25 94 Left 2
SYMATTR Value 0.
SYMATTR InstName Vg1
SYMBOL voltage -80 224 R0
WINDOW 123 0 0 Left 2
SYMATTR SpiceLine Rser=.1
SYMATTR InstName Vg2
SYMATTR Value 110
TEXT -184 64 Left 2 !.dc Va 0 300 1 Vg1 -4 0 0.5
TEXT -528 64 Left 2 !.inc Koren_Tubes.cir
TEXT -328 24 Left 2 ;Ausgangskennlinienfeld ECF82

Gruß, Frank

_________________
Die nächsten Termine Versender von Elektronik und Dampfradiobedarf

Es muss nicht immer alles Sinn machen. Oft reicht es schon, wenn's Spaß macht.


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: PSpice Model ECF82
BeitragVerfasst: Sa Nov 18, 2017 20:39 
Offline

Registriert: So Sep 24, 2017 21:56
Beiträge: 82
Kenntnisstand: Elektrotechnischer Beruf/ Studium
Hallo,
danke für eure Antworten aber ich komme trotzdem nicht voran. Ich hab mir schon gedacht, dass hier Gleichungen fehlen.

Ich bekomme zum Beispiel folgende Fehlermeldungen:
Das Modell enthält mehr Pins als Bauteil. Ich bin mit dieser Schaltungsbeschreibungssprache nicht vertraut aber ich vermute,
dass in der ersten Zeile

[.SUBCKT ECF82P 1 2 3 4 ; A G2 G1 C (Pentode)]

Anschlüsse/Pins deklariert werden. Text nach dem Semikolon gilt als Kommentar. Wenn ich in der ersten Zeile [ A G2 G1 C (Pentode) ] lösche, verschwindet diese Fehlermeldung aber Simulation läuft trotzdem nicht.

Weitere Fehlermeldungen:

[Error] Sheet1 XSpice ERROR - unable to find definition of model 323.2 - default assumed
[Error] Sheet1 XSpice unknown parameter (kp)
[Error] Sheet1 XSpice Error: Unknown variable rgi
[Error] Sheet1 XSpice Error: Could not evaluate value

Hier die komplette Modelbeschreibung der Triode:

.SUBCKT ECF82T 1 2 3 ; P G C (Triode)
* WF data sheet AKA 6U8
* library format: LTSpice 31-May-2008
X1 1 2 3 TRIODE MU=49.87 EX=1.255 KG1=323.2 KP=106.38 KVB=300.0 VCT=0.00 RGI=2000 CCG=3.0p CGP=2.2p CCP=2.3p ;

E1 7 0 VALUE={V(1,3)/KP*LOG(1+EXP(KP*(1/MU+(V(2,3)+VCT)/SQRT(KVB+V(1,3)*V(1,3)))))}
RE1 7 0 1G
G1 1 3 VALUE={(PWR(V(7,0),EX)+PWRS(V(7,0),EX))/KG1}
RCP 1 3 1G ; TO AVOID FLOATING NODES IN MU-FOLLOWER
C1 2 3 {CCG} ; CATHODE-GRID
C2 2 1 {CGP} ; GRID=PLATE
C3 1 3 {CCP} ; CATHODE-PLATE
D3 5 3 DX ; FOR GRID CURRENT
R1 2 5 {RGI} ; FOR GRID CURRENT

.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N) ; diode used by the Triode, Pentode Beam Tetrode models
.ENDS ECF82T

Ist die Syntax richtig?
Oder Frank, könntest du die Modelbeschreibung hier posten, die du verwendet hast?

Viele Grüße, Eugen


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: PSpice Model ECF82
BeitragVerfasst: Sa Nov 18, 2017 22:36 
Offline
Benutzeravatar

Registriert: Sa Jan 09, 2010 15:49
Beiträge: 2705
Wohnort: Sauerland
Kenntnisstand: Elektrotechnischer Beruf/ Studium
Hallo Eugen,

ich benutze LTspice. Obwohl in vielen SUBCKTs der Kommentar "* library format: LTSpice ..." steht, sind Spice-Modelle allgemeingültig.
Ich bin mir aber nicht sicher, ob ein Semikolon im Spicemodell wirklich einen Kommentar einleitet. Bei einem Kommentar beginnt die Zeile immer mit *. Bei LTspice mag das funktionieren, aber bei anderen Simulationsprogrammen?
Welches Simulationsprogramm benutzt Du?

Zumindest für die Pentode der ECF82 fehlen keine Gleichungen in Koren_Tubes.cir.
Die Triode gucke ich mir gleich noch an.

Gruß, Frank

_________________
Die nächsten Termine Versender von Elektronik und Dampfradiobedarf

Es muss nicht immer alles Sinn machen. Oft reicht es schon, wenn's Spaß macht.


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: PSpice Model ECF82
BeitragVerfasst: Sa Nov 18, 2017 22:54 
Offline

Registriert: So Sep 24, 2017 21:56
Beiträge: 82
Kenntnisstand: Elektrotechnischer Beruf/ Studium
Hallo Frank,
ich benutze Altium Designer. Die Software hat natürlich eigene Bibliotheken mit zugehörigen Simulationsmodellen. Wenn ich einem Bauelement ein anderes Simulationsmodell zuweisen will, muss ich eine .ckt Datei anlegen. Im Altium gibt es sowas wie ein Texteditor. (AdvancedSim Sub-Circuit) Man muss die Modellbeschreibung reinschreiben und die Datei abpeichern und dann das gewünschte Bauelement, welches man simulieren möchte, mit dieser .ckt Datei verknüpfen.


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: PSpice Model ECF82
BeitragVerfasst: Sa Nov 18, 2017 23:18 
Offline

Registriert: Do Sep 29, 2016 2:10
Beiträge: 93
Kenntnisstand: Weitergehende Kenntnisse (Hobby)
Hallo Eugen,

ich habe mir aus den großen Librarys für die paar Röhren, die mich interessierten, den entsprechenden Quellcode herausgenommen und in eigene kleine Librarys gesetzt, dies für Triode und Pentode derselben Röhre getrennt. Für die ECF82 habe ich leider Nichts hier.

Ich poste aber mal die Modelle für die ECL/PCL86 Triode- und Pentode-Sektion. Ähnlich könntest Du mit der ECF82 verfahren ("einfach" nur die Zeile mit den Parameter-Zuweisungen durch die Parameter der ECF82 aus Deinem Quellcode austauschen) .

ECL/PCL86 - Triode-Sektion

Code:
******************
* library format: LTSpice 03-Feb-2009
* 1 2 3 ; P G C (Triode)
* Connections: Plate
*              | Grid
*              | | Cathode
*              | | |
.SUBCKT ECL86T 1 2 3
+PARAMS: MU=102.92 EX=1.425 KG1=1754.6 KP=1098.83 KVB=0.5 VCT=0.50 RGI=2000 CCG=3.2p CGP=2.7p CCP=1.8p

******************
E1  7 0 VALUE={V(1,3)/KP*LOG(1+EXP(KP*(1/MU+(V(2,3)+VCT)/SQRT(KVB+V(1,3)*V(1,3)))))}
RE1 7 0 1G
G1  1 3 VALUE={(PWR(V(7,0),EX)+PWRS(V(7,0),EX))/KG1}
RCP 1 3 1G    ; TO AVOID FLOATING NODES IN MU-FOLLOWER
C1  2 3 {CCG}  ; CATHODE-GRID
C2  2 1 {CGP}  ; GRID=PLATE
C3  1 3 {CCP}  ; CATHODE-PLATE
D3  5 3 DX     ; FOR GRID CURRENT
R1  2 5 {RGI}  ; FOR GRID CURRENT

.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N) ; diode used by the Triode, Pentode Beam Tetrode models
.ENDS
******************


Viele Grüße
Steffen

PS: Ich nutze zwar TINA TI und nicht Spice, das Vorgehen sollte aber identisch sein.


Zuletzt geändert von Schiller72 am Sa Nov 18, 2017 23:23, insgesamt 1-mal geändert.

Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: PSpice Model ECF82
BeitragVerfasst: Sa Nov 18, 2017 23:20 
Offline

Registriert: Do Sep 29, 2016 2:10
Beiträge: 93
Kenntnisstand: Weitergehende Kenntnisse (Hobby)
ECL/PCL86 - Pentode-Sektion

Code:
******************
* library format: LTSpice 03-Feb-2009
*              P S G C
* 1 2 3 4 ; A G2 G1 C
* Connections: Plate
*              | Gate
*              | | Source
*              | | | Cathode
*              | | | |
.SUBCKT ECL86_PENTODE 1 2 3 4 ;
+PARAMS: MU=23.15 EX=1.350 KG1=479.1 KG2=4500 KP=128.94 KVB=36.0 VCT=0.00 RGI=2000 CCG=6.7p CPG1=0.6p CCP=4.1p
******************
RE1  7 0  1MEG    ; DUMMY SO NODE 7 HAS 2 CONNECTIONS
E1   7 0  VALUE={V(2,4)/KP*LOG(1+EXP((1/MU+V(3,4)/V(2,4))*KP))}   ; E1 BREAKS UP LONG EQUATION FOR G1.
G1   1 4  VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1*ATAN(V(1,4)/KVB)}
G2   2 4  VALUE={(EXP(EX*(LOG((V(2,4)/MU)+V(3,4)))))/KG2}
* G2   2 4  VALUE={PWR(V(2,4)/MU+V(3,4),EX)/KG2}
RCP  1 4  1G      ; FOR CONVERGENCE   A  - C
C1   3 4  {CCG}   ; CATHODE-GRID 1   C  - G1
C2   1 3  {CPG1}  ; GRID 1-PLATE   G1 - A
C3   1 4  {CCP}   ; CATHODE-PLATE   A  - C
R1   3 5  {RGI}   ; FOR GRID CURRENT   G1 - 5
D3   5 4  DX      ; FOR GRID CURRENT   5  - C

.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N) ; diode used by the Triode, Pentode Beam Tetrode models
.ENDS
******************


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: PSpice Model ECF82
BeitragVerfasst: So Nov 19, 2017 13:38 
Offline

Registriert: Do Nov 17, 2011 23:30
Beiträge: 748
Wohnort: Mannheim
Kenntnisstand: Elektrotechnischer Beruf/ Studium
ek8888 hat geschrieben:
Ich bekomme zum Beispiel folgende Fehlermeldungen:
Das Modell enthält mehr Pins als Bauteil. Ich bin mit dieser Schaltungsbeschreibungssprache nicht vertraut aber ich vermute, dass in der ersten Zeile

[.SUBCKT ECF82P 1 2 3 4 ; A G2 G1 C (Pentode)]

Anschlüsse/Pins deklariert werden. Text nach dem Semikolon gilt als Kommentar. Wenn ich in der ersten Zeile [ A G2 G1 C (Pentode) ] lösche, verschwindet diese Fehlermeldung aber Simulation läuft trotzdem nicht.

Hallo Eugen und Mitleser,

das liegt daran, dass beim Symbol für die Pentode 5 Anschlüsse definiert sind, das Modell ECF82P aber nur 4 Anschlüsse enthält (weil G3 nicht herausgeführt ist, sondern intern mit C verbunden ist).

Das ist aber nicht der einzige Fehler:
Das Symbol Pentode in LTspice erwartet die Anschlussfolge C G1 G2 G3 A.
Das Modell ECF82P hat die Anschlussfolge A G2 G1 C, also in genau umgekehrter Reihenfolge.

Die Reihenfolge der Anschlüsse wurde bei den ursprünglichen SPICE-Versionen definiert, da sind aber keine Röhren dabei. Hier sind nicht nicht alle Versionen gleich. (Ähnlich MOSFET-Modelle von infineon, die eine andere Anschlussfolge haben als die LTspice-Symbole.)

Ein weiterer Fehler, der manchmal auftritt: Exponenten in Gleichungen werden bei PSpice durch "^" dargestellt, bei LTspice durch "**". Das habe ich in der Modelldatei aber nicht entdeckt, außer im Beschreibungstext, wo es nicht stört.

Für LTspice habe ich ein passendes Symbol für das Modell ECF82P erzeugt.
Die Datei nannte ich pentode_4pin.asy
Code:
Version 4
SymbolType CELL
LINE Normal -48 -16 -48 16
LINE Normal 48 -16 48 16
LINE Normal 0 -64 0 -32
LINE Normal -20 -32 20 -32
LINE Normal -20 -28 20 -28
LINE Normal -20 -32 -20 -28
LINE Normal 20 -32 20 -28
LINE Normal 20 -16 12 -16
LINE Normal 4 -16 -4 -16
LINE Normal -12 -16 -20 -16
LINE Normal 48 0 28 0
LINE Normal 20 0 12 0
LINE Normal 4 0 -4 0
LINE Normal -12 0 -20 0
LINE Normal -48 16 -28 16
LINE Normal -20 16 -12 16
LINE Normal -4 16 4 16
LINE Normal 12 16 20 16
LINE Normal -24 28 24 28
LINE Normal -32 64 -32 36
LINE Normal -24 28 -32 36
LINE Normal 24 28 32 36
LINE Normal -28 32 28 32
ARC Normal -48 -64 48 32 48 -16 -48 -16
ARC Normal -48 -32 48 64 -48 16 48 16
WINDOW 0 8 -80 Left 2
WINDOW 3 -24 80 Left 2
SYMATTR Value Pentode 4 pin
SYMATTR Prefix X
SYMATTR Description Pentode with 4 accessible pins. Pinorder: A G2 G1 C
PIN -32 64 NONE 0
PINATTR PinName Cathode
PINATTR SpiceOrder 4
PIN -48 16 NONE 0
PINATTR PinName G1
PINATTR SpiceOrder 3
PIN 48 0 NONE 0
PINATTR PinName G2
PINATTR SpiceOrder 2
PIN 0 -64 NONE 0
PINATTR PinName Anode
PINATTR SpiceOrder 1

Viel Erfolg beim Weitersimulieren

Bernhard


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: PSpice Model ECF82
BeitragVerfasst: So Nov 19, 2017 16:19 
Offline
Benutzeravatar

Registriert: Sa Jan 09, 2010 15:49
Beiträge: 2705
Wohnort: Sauerland
Kenntnisstand: Elektrotechnischer Beruf/ Studium
Hallo zusammen,
für LTspice-User: Beide Modelle funktionieren, also für Pentode und Triode der ECF82.
Um die Modelldatei einzubinden, gibt es LTspice zwei Möglichkeiten (die mir gerade einfallen):

1. Der Library-Name steht in der (von der .ASC-Datei eingeladenen) Symboldatei (z.B. TRIODE.ASY) in dieser Zeile:
SYMATTR ModelFile Tube.lib
Hier wäre also "Tube.lib" die Library, stattdessen könnte dort auch "Koren_Tubes.cir" stehen.
Nachteil: Für jedes neue Modell braucht man eine neue Symboldatei.

2. In der Symboldatei (z.B. TRIODE.ASY) fehlt die Zeile
SYMATTR ModelFile ...
Dafür wird die Modelldatei von der .ASC-Datei includiert, mit
.INC Koren_Tubes.cir
Auch hier könnte statt "Tube.lib" auch "Koren_Tubes.cir" stehen.

Eugen, weil der Altium Designer das Semikolon offenbar nicht als Kommentareinleitung akzeptiert, habe ich mal testweise in der kompletten Koren_Tubes.cir jedes Semikolon incl. nachfolgenden Textes bis zum Zeilenende gelöscht. Und: Die Simulation läuft immer noch sauber.
Probier's doch mal, vielleicht funktioniert es dann mit dem Altium Designer auch.

Gruß, Frank

_________________
Die nächsten Termine Versender von Elektronik und Dampfradiobedarf

Es muss nicht immer alles Sinn machen. Oft reicht es schon, wenn's Spaß macht.


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: PSpice Model ECF82
BeitragVerfasst: So Nov 19, 2017 17:36 
Offline

Registriert: Do Nov 17, 2011 23:30
Beiträge: 748
Wohnort: Mannheim
Kenntnisstand: Elektrotechnischer Beruf/ Studium
Bosk Veld hat geschrieben:
Hallo zusammen,
für LTspice-User: Beide Modelle funktionieren, also für Pentode und Triode der ECF82.
...
Eugen, weil der Altium Designer das Semikolon offenbar nicht als Kommentareinleitung akzeptiert, habe ich mal testweise in der kompletten Koren_Tubes.cir jedes Semikolon incl. nachfolgenden Textes bis zum Zeilenende gelöscht. Und: Die Simulation läuft immer noch sauber.
Probier's doch mal, vielleicht funktioniert es dann mit dem Altium Designer auch.

Hallo Frank,

mit LTspiceXVII erhalte ich sinngemäß die gleiche Meldung wie Eugen:
"Port(pin) count mismatch between the definition of subcircuit "ecf82p" and instance: "xu1"
The instance has more connection terminals than the definition."


Das liegt nicht am Strichpunkt, sondern am Symbol: Dein Symbol "pentode" hat nur 4 Anschlüsse, das Standard-Symbol "pentode.asy" in LTspice hat 5 Anschlüsse und andere Anschlussfolge.

Ich nehme an, bei anderen Simulatoren haben Pentoden standardmäßig auch 5 Anschlüsse.

Gruß Bernhard


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: PSpice Model ECF82
BeitragVerfasst: So Nov 19, 2017 17:47 
Offline

Registriert: So Sep 24, 2017 21:56
Beiträge: 82
Kenntnisstand: Elektrotechnischer Beruf/ Studium
Hallo Steffen, Frank, Bernhard und andere Mitleser.

Steffen, vielen Dank für die Quellcodes. Genau in der Form brauche ich diese Modellbeschreibungen. Leider funktionieren sie bei mir nicht. Ich denke, es liegt daran, dass die im LTSpice-Format geschriebn sind. Es kommt zur Fehlermeldung "[Error] Iteration limit reached". Die sagt nicht viel aus. Zur der Fehlermeldung kommt es auch wenn zum Beispiel ein Bauteil nicht angeschlossen ist.

Bernhard, danke für die Tipps. Ich hab ein wenig mit dem Quellcode gespielt und es kam zu Fehlermeldung - PWR: unknown parameter. PWR ist ein Befehl für Potenzfunktion. Ich denke, diese Befehle für Potenzfunktionen werden nicht erkannt und man muss sie durch "^" darstellen.

Weiß jemand was die Zahlen 7 und 0 in der Zeile bedeuten?
Code:
E1  7 0 VALUE={V(1,3)/KP*LOG(1+EXP(KP*(1/MU+(V(2,3)+VCT)/SQRT(KVB+V(1,3)*V(1,3)))))}


Die Zahlen 2 und 3 in de Zeile
Code:
C1  2 3 {CCG}  ; CATHODE-GRID
sind mir klar. Das ist die Kapazität zwischen den definierten Anschlüssen 2 und 3. Aber 7 und 0???

Also, ich glaube man muss den Quellcode, den Steffen gepostet hat, einfach irgendwie umschreiben/umformatieren damit Altium Designer nicht mekert.

Hier sind einige Quellcodes, die ich aus Altium Bibliotheken rauskopiert habe. Sie Funktionieren. Hier sieht man zum Beispiel, dass Befehl PWR nicht verwendet wird, sondern "^".

Code:
*Vacuum Tube Tetrode (Audio freq.)
*Connections:
*             Plate
*             | Screen
*             | | Grid
*             | | | Cathode
*             | | | |
.SUBCKT 6L6GC 1 6 3 4
B1 2 4 I=(((URAMP((V(7,4)/8)+V(3,4)))^1.5)/1456)*ATAN(V(1,4)/10)
B2 7 4 I=((URAMP((V(7,4)/8)+V(3,4)))^1.5)/9270
C1 3 4 10P
C2 3 1 0.6P
C3 1 4 6.5P
R1 3 5 1.5K
R2 2 4 100K
D1 1 2 DX
D2 4 2 DX2
D3 5 4 DX
D4 6 7 DX
D5 4 7 DX2
.MODEL DX D(IS=1.0P RS=1.0)
.MODEL DX2 D(IS=1.0N RS=1.0)
.ENDS 6L6GC



*Vacuum Tube Dual Triode (Audio freq.)
*Connections:
*              Plate 1
*              | Grid 1
*              | | Cathode 1
*              | | | Plate 2
*              | | | | Grid 2
*              | | | | | Cathode 2
*              | | | | | | H H
*              | | | | | | | |
.SUBCKT 6SN7   2 1 3 5 4 6 7 8
X1 2 1 3  6SN7s
X2 5 4 6 6SN7s
RH1 7 8 100
.ENDS 6SN7

*Vacuum Tube Triode (Audio freq.)
*Connections:
*            Plate
*            | Grid
*            | | Cathode
*            | | |
.SUBCKT 6SN7s 1 3 4
B1 2 4 I=((URAMP((V(2,4)/20)+V(3,4)))^1.5)/1086
C1 3 4 2.6E-12
C2 3 1 4.0E-12
C3 1 4 0.7E-12
R1 3 5 10E+3
D1 1 2 DX
D2 4 2 DX2
D3 5 4 DX
.MODEL DX D(IS=1.0E-12 RS=1.0)
.MODEL DX2 D(IS=1.0E-9 RS=1.0)
.ENDS 6SN7s


*Vacuum Tube Pentode and Triode (Audio freq.)
*Connections:
*            Plate 1
*            | Grid 1
*            | | Cathode 1
*            | | | Plate 2
*            | | | | Grid 2
*            | | | | | Grid 3
*            | | | | | | Cathode 2
*            | | | | | | | Heater
*            | | | | | | | | Heater
*            | | | | | | | | |
.SUBCKT 7199 1 9 8 2 3 7 6 4 5
X1 1 9 8 7199T
X2 2 3 7 6 7199P
RH 4 5 100
.ENDS 7199

*Vacuum Tube Triode (Audio freq.)
*Connections:
*             Plate
*             | Grid
*             | | Cathode
*             | | |
.SUBCKT 7199T 1 3 4
B1 2 4 I=((URAMP((V(2,4)/17)+V(3,4)))^1.5)/711
C1 3 4 2.3E-12
C2 3 1 2.0E-12
C3 1 4 0.3E-12
R1 3 5 5E+3
D1 1 2 DX
D2 4 2 DX2
D3 5 4 DX
.MODEL DX D(IS=1.0E-12 RS=1.0)
.MODEL DX2 D(IS=1.0E-9 RS=1.0)
.ENDS 7199T

*Vacuum Tube Tetrode (Audio freq.)
*Connections:
*             Plate
*             | Screen
*             | | Grid
*             | | | Cathode
*             | | | |
.SUBCKT 7199P 1 6 3 4
B1 2 4 I=(((URAMP((V(7,4)/20)+V(3,4)))^1.5)/1206)*ATAN(V(1,4)/10)
B2 7 4 I=((URAMP((V(7,4)/20)+V(3,4)))^1.5)/2562
C1 3 4 5.0P
C2 3 1 0.06P
C3 1 4 2.0P
R1 3 5 5K
R2 2 4 2.5MEG
D1 1 2 DX
D2 4 2 DX2
D3 5 4 DX
D4 6 7 DX
D5 4 7 DX2
.MODEL DX D(IS=1.0P RS=1.0)
.MODEL DX2 D(IS=1.0N RS=1.0)
.ENDS 7199P


*--------------------------------------------------------------------------
* Specialized tube model
*
*    Type           : 12AX7 ECC83 6N2P
*    Description    : Triode
*    Direct heated  : no
*    Screen present : no
*--------------------------------------------------------------------------
.subckt 12AX7 P G K
Bp P K I=((0.001149607902m)+(0.0001063352726m)*V(G,K))*uramp((91.16514401)*V(G,K)+V(P,K)+(52.29904339))**1.5 * V(P,K)/(V(P,K)+(2.177964467))
Cgp G P 1.7pF
Cgk G K 1.6pF
Cpk P K 0.46pF
.ends 12AX7


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: PSpice Model ECF82
BeitragVerfasst: So Nov 19, 2017 18:57 
Offline

Registriert: Do Nov 17, 2011 23:30
Beiträge: 748
Wohnort: Mannheim
Kenntnisstand: Elektrotechnischer Beruf/ Studium
ek8888 hat geschrieben:
...Weiß jemand was die Zahlen 7 und 0 in der Zeile bedeuten?
Code:
E1  7 0 VALUE={V(1,3)/KP*LOG(1+EXP(KP*(1/MU+(V(2,3)+VCT)/SQRT(KVB+V(1,3)*V(1,3)))))}

Die Zahlen 2 und 3 in de Zeile
Code:
C1  2 3 {CCG}  ; CATHODE-GRID
sind mir klar. Das ist die Kapazität zwischen den definierten Anschlüssen 2 und 3. Aber 7 und 0???

"E1" ist eine gesteuerte Spannungsquelle. Deren Ausgang liegt zwischen den Knoten 7 und 0.
Die Ausgangsspannung wird durch die Formel hinter "VALUE=" berechnet.

"C1" ist ein Kondensator zwischen den Knoten 2 und 3.
Nach den Anschlussknoten folgt die Kapazität in Farad, die ist hier in Form eines Parameters "CCG" angegeben. Parameter werde in geschweiften Klammern geschrieben. "CCG" muss dann irgendwo definiert sein.
Wäre der Wert fest und würde beispielsweise 5 nF betragen, würde die Zeile lauten
C1 2 3 5n

Zu einem "Knoten" gehören alle Leitungen, die damit verbunden sind.
Der Knoten "0" ist das sumulations-interne Bezugspotential, das häufig mit dem Massepotential gleichgesetzt wird.
Alle Spannungen an Knoten werden auf das Potential des Knoten "0" bezogen.

Bernhard

PS: Zum Einstieg in die Schaltungssimulation kann ich das deutschsprachige Tutorial von Gunthard Kraus empfehlen. Gunthard verwendet LTspice, die Grundlagen sind aber bei allen Simulatoren fast gleich, die auf SPICE3 (University of California, Berkeley) aufbauen.
Homepage von Gunthard Kraus: http://www.gunthard-kraus.de
Direktlink zum Tutorial (22 MB): http://www.gunthard-kraus.de/LTSwitcher ... l_2017.pdf

Edit: PS ergänzt


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: PSpice Model ECF82
BeitragVerfasst: So Nov 19, 2017 20:01 
Offline

Registriert: So Sep 24, 2017 21:56
Beiträge: 82
Kenntnisstand: Elektrotechnischer Beruf/ Studium
Sicher, dass es eine Spannungsquelle ist? Die Funktion
Code:
VALUE={V(1,3)/KP*LOG(1+EXP(KP*(1/MU+(V(2,3)+VCT)/SQRT(KVB+V(1,3)*V(1,3)))))}
berchnet doch den Strom. Oder nicht?
Ich habs mir schon gedacht, dass Knoten 0 sich auf Masse bezieht. Aber wo ist denn der Knoten 7? Der ist doch nicht definiert.


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: PSpice Model ECF82
BeitragVerfasst: So Nov 19, 2017 21:05 
Offline

Registriert: Do Nov 17, 2011 23:30
Beiträge: 748
Wohnort: Mannheim
Kenntnisstand: Elektrotechnischer Beruf/ Studium
ek8888 hat geschrieben:
Sicher, dass es eine Spannungsquelle ist? Die Funktion
Code:
VALUE={V(1,3)/KP*LOG(1+EXP(KP*(1/MU+(V(2,3)+VCT)/SQRT(KVB+V(1,3)*V(1,3)))))}
berchnet doch den Strom. Oder nicht?

E... ist immer eine Spannungsquelle, so ist dieses "Bauteil" definiert. VALUE ergibt dann die Spannung in V.
Im obigen Beispiel ergibt die Formel auch einen Spannungswert:
"V(1,3)" ist die Spannung zwischen den Knoten 1 und 3. Dieser Spannungswert wird durch irgendeinen Zahlenwert dividiert "/", der mit "KP*..." beginnt. Das ergibt wieder eine Spannung.

ek8888 hat geschrieben:
Ich habs mir schon gedacht, dass Knoten 0 sich auf Masse bezieht. Aber wo ist denn der Knoten 7? Der ist doch nicht definiert.

Die Spannung an Knoten 7 stellt sich während der Simulation ein, ihr Wert wird bei jedem Simulationsschritt neu berechnet. An diesem Knoten hängt auch RE1. Der wird durch die Zeile
RE1 7 0 1G
definiert. Er liegt also auch zwischen den Knoten 7 und 0 (d. h. parallel zu E1) und hat den Wert 1 GOhm.

****

Kleiner Grundlagenausflug:
Egal welcher SPICE-basierter Simulator verwendet wird:

Der Schaltplaneditor erzeugt eine Netzliste, die dem Simulator übergeben wird. (Die Netzliste ist relativ klein, siehe unten. Zur Not geht es auch ohne Schaltplaneditor.)

Die Netzliste ist die zentrale Datei, die der SPICE-Syntax folgt. Sie enthält die Bauteile und Anweisungen für den Simulator. Die Datei trägt meistens die Endung .cir oder .net

Beispiel: Die .asc-Datei (aus LTspice) von Frank erzeugt folgende Simulationsdatei:
Code:
* C:\Users\Bernhard\Work\Roehren\test.asc
XU1 0 g1 g2 NC_01 a ECF82P
Va a 0 250
Vg1 g1 0 0.
Vg2 g2 0 110 Rser=.1
.dc Va 0 300 1 Vg1 -4 0 0.5
.inc Koren_Tubes.cir
* Ausgangskennlinienfeld ECF82
.backanno
.end

X... ist ein separater Schaltungsblock (sub circuit)
V... ist eine Spannungsquelle
.dc ist die Anweisung für eine statische (Gleichstrom-)Analyse: Ändere die Spannungen Va und Vg1 mit Startwert, Endwert und Schrittweite
.inc ist die Anweisung, die folgende Datei (die weitere Bauteile enthält) einzubetten (include)
.backanno ist die Anweisung für LTspice, die Bauteilnamen in die Ausgabedatei aufzunehmen
.end ist die Anweisung, das Einlesen der Netzliste zu beenden.

Konventionen:
Bauteile beginnen mit einem Buchstaben
Anweisungen für den Simulator beginnen mit einem Punkt "."
Kommentartexte beginnen mit einem Stern "*" (diese Zeilen werden vom Simulator nicht gelesen)
Leerzeichen trennen die einzelnen Attribute, ihre Anzahl ist beliebig
Besonderheiten:
Die erste Zeile wird immer als Text betrachtet, egal mit welchem Zeichen sie beginnt.
Leerzeichen am Zeilenanfang werden von einigen Simulatoren auch als Text betrachtet und nicht gelesen. Einrücken ist also verboten.

Alles Weitere kann man in der SPICE-Literatur nachlesen.
Wer englisch versteht: Die Onlinehilfe zu LTspice finde ich auch gut.


Nach oben
 Profil  
Mit Zitat antworten  
Beiträge der letzten Zeit anzeigen:  Sortiere nach  
Ein neues Thema erstellen Auf das Thema antworten  [ 19 Beiträge ]  Gehe zu Seite 1, 2  Nächste

Alle Zeiten sind UTC + 1 Stunde


Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 1 Gast


Sie dürfen keine neuen Themen in diesem Forum erstellen.
Sie dürfen keine Antworten zu Themen in diesem Forum erstellen.
Sie dürfen Ihre Beiträge in diesem Forum nicht ändern.
Sie dürfen Ihre Beiträge in diesem Forum nicht löschen.
Sie dürfen keine Dateianhänge in diesem Forum erstellen.

Suche nach:
Gehe zu:  
POWERED_BY
Deutsche Übersetzung durch phpBB.de

 
Impressum